{
  inputs = {
    agenix = {
      url = "github:ryantm/agenix";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.darwin.follows = "";
    };
    nixpkgs.url = "nixpkgs/nixos-23.05";
  };

  outputs = { self, nixpkgs, agenix, ... }@attrs:
    let
      pkgs = import nixpkgs { inherit system; };
      shell = import ./shell.nix { inherit agenix pkgs; };
      system = "x86_64-linux";
    in {
      devShell.x86_64-linux = shell.dev;

      formatter.x86_64-linux = nixpkgs.legacyPackages.x86_64-linux.nixfmt;

      nixosConfigurations = {
        eve-psr-nix0 = nixpkgs.lib.nixosSystem {
          inherit system;
          specialArgs = attrs;
          modules = [
            ({ modulesPath, ... }: {

              imports = [
                agenix.nixosModules.default

                ./system/containers.nix
                ./system/hardware-configuration.nix
                ./system/nix-configuration.nix
                ./system/security.nix
                ./system/services.nix
                ./system/system.nix
                ./system/virtualisation.nix

                ./user/users.nix
              ];

              age = {
                secrets = {
                  keys.file = ./secrets/keys.age;
                  sezycei.file = ./secrets/sezycei.age;
                };
                identityPaths = [ "/etc/ssh/ssh_host_ed25519_key" ];
              };

              system.stateVersion = "22.11";
            })
          ];
        };
      };
    };
}